MP3 speech files for use in clock projects

Ideally it sounds like software for your computer to do this would be the best option. However, Arduino is an alternative way. If I understand correctly, you have not used Arduino before so I’ll provide a bit more info about that. Sorry if you already know this. Arduino consists of programming software and standalone hardware. The hardware is based around cheap microcontrollers that are supplied on a development board that have additional support parts to get them up and running fairly easily. Included on many boards including the Nano is a USB socket to allow it all to be easily programmed by a Mac, Windows or Linux computer.

They were designed to make it easier to program to allow more people to make things. Many people that have done programming before are surprised at how quickly they can get going with it. I expect anyone that has never programmed before to find it a bit more challenging but still doable.

The Arduino Nano doesn’t have a built-in clock, but it does have a timer that begins counting up as soon as it is powered. The timer counts in milliseconds and while it is useful for many things it is not as accurate as a clock. I’ve pasted in a simple program below for the Nano that uses the timer to play a random track every set number of minutes. The code may give you an idea if this is the sort of thing you want to take on or not.

// ==================================================================
//   Demo sketch for Random track player using MP3 DFPlayer module
// ==================================================================
/*
   Connections
   ===========
   DFPlayer ground pin 7 and/or 10
   DFPlayer power pin 1 to 3.3 - 5V VCC
   Arduino TX (pin 9) - DFPlayer RX (pin 2) via 1k resistor

   DFplayer Output
   --------------
   Speaker to pin 6 (speaker +) and 8 (Speaker -)
   OR
   Audio output right channel - pin 4
   Audio output left channel - pin 5

   Audio files
   ===========
   This demo requires files with filenames starting with a 3 digit number starting with 001 
   and placed in a folder named 01 on the SD card 

   Delays
   ======
   The 2000 ms delays in this sketch are this length for my slowest player. Try reducing or removing for other players
*/

#include  // Library for cummunication with DFPlayer

// DFPlayer audio module connections
#define mp3RxPin 10         // Pin for receiving commands from the DFPlayer - Not used or connected in this sketch
#define mp3TxPin 9          // Pin for sending commands to the player (Player pin 2)

// Set these for your preference
long delayTime = 2;         // Number of minutes between plays
int numberOfTracks = 72;    // Update this to store the number of tracks on the SD card
int playerVolume = 10;      // Set player volume: 0 - 30
int equalizerSetting = 0;   // Player equalizer: Normal = 0 / Pop = 1 / Rock = 2 / Jazz = 3 / Classic = 4 / Bass = 5

// These are used and updated by the sketch
long thisTrackNumber;       // For storing the track that is to be played
long lastTrackTime = 0;     // For keeping track of when the last time a track was played
long nextTrackTime = 0;     // For storing the time the next track is due to play
long thisTrackTime = 0;     // For storing when the current track played

// Set up software serial instead of serial to allow serial monitor to be used
SoftwareSerial mp3(mp3RxPin, mp3TxPin);

// --------------------- SETUP ---------------------
void setup() {

  // Use random noise values from the unconnected A0 pin to seed the random number generator
  randomSeed(analogRead(0));

  // For comms to MP3 player
  mp3.begin(9600);

  // Wait for player to initialize
  delay(2000);

  // Set volume
  sendCommand(0x06, 0, playerVolume);
  delay(2000);

  // Set equalizer  
  sendCommand(0x07, 0, equalizerSetting);
  delay(2000);
}

// --------------------- MAIN LOOP ---------------------
void loop() {
  // This loops around continuously while the Arduino is on
  
  // Check if enough time has elapsed to play a track
  if (millis() > nextTrackTime) {

    // Remember the time this track played
    thisTrackTime = nextTrackTime;
    
    // Select a random track and play it
    thisTrackNumber = 1 + random(numberOfTracks); // Choose track
    sendCommand(0x0F, 1, thisTrackNumber); // Play the track
    
    // Update the time to play the next track
    // The millis counter uses milliseconds. Multiply by 60 000 to get minutes
    nextTrackTime = thisTrackTime + (60000 * delayTime);
    
    // Remember when the last time a track was played
    lastTrackTime = thisTrackTime;
  }
}

// --------------------- SEND COMMANDS TO DFPLAYER ---------------------
void sendCommand(byte Command, byte Param1, byte Param2) {
  // Format command including checksum and send to DFPlayer 

  // For DFPlayer communication
  const byte startByte = 0x7E;    // Start Command
  const byte versionByte = 0xFF;  // Version info
  const byte dataLength = 0x06;   // Fixed 0x06 Data length not including parity
  const byte infoReq = 0x00;      // Get info back from module - 0x00 = no info, 0x01 = return info
  const bool isDebug = false;     // Debug mode - Off in this sketch
  const byte endByte = 0xEF;      // Fixed end Command

  // Calculate the checksum
  unsigned int checkSum = -(versionByte + dataLength + Command + infoReq + Param1 + Param2);

  // Construct the command line
  byte commandBuffer[10] = { startByte, versionByte, dataLength, Command, infoReq, Param1, Param2,
      highByte(checkSum), lowByte(checkSum), endByte };

  // Send to player
  for (int cnt = 0; cnt < 10; cnt++) {
    mp3.write(commandBuffer[cnt]);
  }

  // Delay needed between successive commands
  delay(30);
}

I've added in lots of comments to provide info about each bit. In this example delayTime and numberOfTracks need to be changed to the number of minutes between each play and the total number of tracks in the SD card folder.

Tracks need to be placed on a Micro SD card in a folder and each track needs to start with a 3 digit number starting with 001. The rest of the filename is not important. The DFPlayer just looks at the first three digits.

This creates a standalone project. If you are still interested, I recommend having a look more at Arduino. I usually buy parts from eBay and I expect the Nano and DFPlayer would cost around US$10 - $15 for the two. A good speaker can cost more but you may already have one of those.

LikeLike